Engine/testapp/build.gradle

plugins {
    id 'java'
    id 'application'
    id 'io.freefair.lombok' version "${pluginLombok}"
    id 'com.github.johnrengelman.shadow' version "${pluginShadow}"
}

dependencies {
    // -> Runtime <-
    // Lombok
    compileOnly 'org.projectlombok:lombok:' + project.dependencyLombok
    annotationProcessor 'org.projectlombok:lombok:' + project.dependencyLombok

    // JetBrains Annotations
    compileOnly 'org.jetbrains:annotations:' + project.dependencyJetbrainsAnnotations

    // -> Project <-
    implementation project(":base")
    implementation project(":slf4j-compat")
    implementation project(":graphics")
    implementation project(":graphics:vulkan")
    implementation project(":graphics:opengl")
}

javadoc.options {
    setMemberLevel(JavadocMemberLevel.PUBLIC)
    setOverview("src/main/javadoc/overview.html")
    setLocale("en_US")
    setJFlags([
            // Force Javadoc to use English translations
            "-Duser.language=en_US"
    ])
}

jar {
    manifest {
        attributes(
                'Main-Class': 'de.staropensource.sosengine.testapp.Main'
        )
    }
}

application {
    mainClass.set("de.staropensource.sosengine.testapp.Main")
    applicationDefaultJvmArgs = [
            // Set log level to DIAGNOSTIC
            "-Dsosengine.base.loggerLevel=diagnostic",

            // Force writing to standard output
            "-Dsosengine.base.loggerForceStandardOutput=true",

            // Force Jansi to write escape sequences
            "-Djansi.mode=force",
    ]
}