/*
 * STAROPENSOURCE ENGINE SOURCE FILE
 * Copyright (c) 2024 The StarOpenSource Engine Contributors
 * Licensed under the GNU Affero General Public License v3
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

import org.gradle.internal.os.OperatingSystem

plugins {
    id("java")
    id("io.freefair.lombok") version("${pluginLombok}")
}

// Determine LWJGL native stuff
switch (OperatingSystem.current()) {
    case OperatingSystem.LINUX:
        project.dependencyLwjglNatives = "natives-linux"
        def osArch = System.getProperty("os.arch")
        if (osArch.startsWith("arm") || osArch.startsWith("aarch64")) {
            project.dependencyLwjglNatives += osArch.contains("64") || osArch.startsWith("armv8") ? "-arm64" : "-arm32"
        } else if  (osArch.startsWith("ppc")) {
            project.dependencyLwjglNatives += "-ppc64le"
        } else if  (osArch.startsWith("riscv")) {
            project.dependencyLwjglNatives += "-riscv64"
        }
        break
    case OperatingSystem.MAC_OS:
        project.dependencyLwjglNatives = System.getProperty("os.arch").startsWith("aarch64") ? "natives-macos-arm64" : "natives-macos"
        break
    case OperatingSystem.WINDOWS:
        def osArch = System.getProperty("os.arch")
        project.dependencyLwjglNatives = osArch.contains("64")
                ? "natives-windows${osArch.startsWith("aarch64") ? "-arm64" : ""}"
                : "natives-windows-x86"
        break
}

dependencies {
    // -> Runtime <-
    // Lombok
    compileOnly("org.projectlombok:lombok:${dependencyLombok}")
    annotationProcessor("org.projectlombok:lombok:${dependencyLombok}")

    // JetBrains Annotations
    compileOnly("org.jetbrains:annotations:${dependencyJetbrainsAnnotations}")

    // LWJGL
    implementation(platform("org.lwjgl:lwjgl-bom:${dependencyLwjgl}"))
    implementation("org.lwjgl:lwjgl")
    implementation("org.lwjgl:lwjgl-bgfx")
    implementation("org.lwjgl:lwjgl-egl")
    implementation("org.lwjgl:lwjgl-glfw")
    implementation("org.lwjgl:lwjgl-ktx")
    implementation("org.lwjgl:lwjgl-opengl")
    implementation("org.lwjgl:lwjgl-opengles")
    implementation("org.lwjgl:lwjgl-shaderc")
    implementation("org.lwjgl:lwjgl-sse")
    implementation("org.lwjgl:lwjgl-vma")
    runtimeOnly("org.lwjgl:lwjgl::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-bgfx::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-glfw::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-ktx::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-opengl::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-opengles::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-shaderc::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-sse::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-vma::${dependencyLwjglNatives}")
    if (project.dependencyLwjglNatives == "natives-macos" || project.dependencyLwjglNatives == "natives-macos-arm64") runtimeOnly("org.lwjgl:lwjgl-vulkan::${dependencyLwjglNatives}")

    // -> Testing <-
    // Jetbrains Annotations
    testCompileOnly("org.jetbrains:annotations:${dependencyJetbrainsAnnotations}")

    // JUnit
    testImplementation(platform("org.junit:junit-bom:${dependencyJunit}"))
    testImplementation("org.junit.jupiter:junit-jupiter")
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")

    // jOOR
    testImplementation("org.jooq:joor:${dependencyJoor}")

    // -> Project <-
    implementation(project(":base"))
    implementation(project(":graphics"))
    implementation("org.fusesource.jansi:jansi:${dependencyJansi}")  // for some reason required or the build fails don"t ask me why
}

javadoc.options {
    setMemberLevel(JavadocMemberLevel.PUBLIC)
    setOverview("src/main/javadoc/overview.html")
    setLocale("en_US")
    setJFlags([
            // Force Javadoc to use English translations
            "-Duser.language=en_US"
    ])
}

test {
    useJUnitPlatform()
    testLogging {
        events("passed", "skipped", "failed")
    }
}