/*
 * STAROPENSOURCE ENGINE SOURCE FILE
 * Copyright (c) 2024 The StarOpenSource Engine Authors
 * Licensed under the GNU Affero General Public License v3
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

import org.gradle.internal.os.OperatingSystem

// Plugins
plugins {
    id("java")
    id("io.freefair.lombok") version("${pluginLombok}")
    id("maven-publish")
}

// Dependencies
dependencies {
    // Lombok
    compileOnly("org.projectlombok:lombok:${dependencyLombok}")
    annotationProcessor("org.projectlombok:lombok:${dependencyLombok}")

    // JetBrains Annotations
    compileOnly("org.jetbrains:annotations:${dependencyJetbrainsAnnotations}")

    // LWJGL
    implementation(platform("org.lwjgl:lwjgl-bom:${dependencyLwjgl}"))
    implementation("org.lwjgl:lwjgl")
    implementation("org.lwjgl:lwjgl-glfw")
    implementation("org.lwjgl:lwjgl-stb")
    runtimeOnly("org.lwjgl:lwjgl::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-glfw::${dependencyLwjglNatives}")
    runtimeOnly("org.lwjgl:lwjgl-stb::${dependencyLwjglNatives}")
    if (project.dependencyLwjglNatives == "natives-macos" || project.dependencyLwjglNatives == "natives-macos-arm64") runtimeOnly("org.lwjgl:lwjgl-vulkan::${dependencyLwjglNatives}")

    // Project
    implementation(project(":base"))
    implementation(project(":windowing"))
}

// Javadoc configuration
javadoc {
    outputs.upToDateWhen { false }  // Force task execution
    dependsOn(delombok)  // Make sure the source is delomboked first

    javadoc {
        setClasspath(files(project.sourceSets.main.compileClasspath))  // Include dependencies

        options {
            if (new File(projectDir, "src/main/javadoc/theme.css").exists())
                stylesheetFile = new File(projectDir, "src/main/javadoc/theme.css")  // Theming is cool :3
            setMemberLevel(JavadocMemberLevel.PUBLIC)  // Only display public stuff
            setOverview("src/main/javadoc/overview.html")  // We want a custom overview page to greet the visitor
            setLocale("en_US")  // 你好
            addStringOption("Xwerror", "-quiet") // Fail build on warning

            setJFlags([
                    "-Duser.language=en_US"  // See above
            ])
        }
    }
}

// Unit testing configuration
test {
    useJUnitPlatform()

    // Pass test configuration to test VMs
    Map<String, String> testConfiguration = new HashMap<>()
    for (String property : project.properties.keySet())
        if (property.startsWith("test."))
            testConfiguration.put(property, project.properties.get(property).toString())
    systemProperties(testConfiguration)

    setMaxParallelForks(project.hasProperty("jobs") ? Integer.parseInt((String) project.property("jobs")) : 8)
    setForkEvery(1)
    setFailFast(true)

    testLogging {
        events("passed", "skipped", "failed")
    }
}

// Include javadoc and source jar during publishing
java {
    withJavadocJar()
    withSourcesJar()
}

// Build publishing configuration
// Note: You can safely ignore any errors or warnings thrown by your IDE here
publishing {
    repositories {
        maven {
            name = "staropensource"
            url = uri("https://mvn.staropensource.de/sosengine")
            credentials(org.gradle.api.credentials.PasswordCredentials)
            authentication {
                //noinspection GroovyAssignabilityCheck
                basic (BasicAuthentication)
            }
        }
    }
    publications {
        //noinspection GroovyAssignabilityCheck
        maven (MavenPublication) {
            groupId = group
            artifactId = project.getName()
            version = version
            //noinspection GroovyAssignabilityCheck
            from components.java
        }
    }
}

// Determine operating system and architecture
switch (OperatingSystem.current()) {
    case OperatingSystem.LINUX:
        project.dependencyLwjglNatives = "natives-linux"
        def osArch = System.getProperty("os.arch")
        if (osArch.startsWith("arm") || osArch.startsWith("aarch64"))
            project.dependencyLwjglNatives += osArch.contains("64") || osArch.startsWith("armv8") ? "-arm64" : "-arm32"
        else if (osArch.startsWith("ppc"))
            project.dependencyLwjglNatives += "-ppc64le"
        else if (osArch.startsWith("riscv"))
            project.dependencyLwjglNatives += "-riscv64"
    case OperatingSystem.MAC_OS:
        project.dependencyLwjglNatives = System.getProperty("os.arch").startsWith("aarch64") ? "natives-macos-arm64" : "natives-macos"
    case OperatingSystem.WINDOWS:
        def osArch = System.getProperty("os.arch")
        project.dependencyLwjglNatives = osArch.contains("64")
                ? "natives-windows${osArch.startsWith("aarch64") ? "-arm64" : ""}"
                : "natives-windows-x86"
}

// Fix delombok task
delombok.doFirst {
    File target = file("${project.projectDir}/src/main/module-info.java")
    File source = file("${project.projectDir}/src/main/java/module-info.java")

    target.delete()
    source.renameTo(target)
}
delombok.doLast {
    File target = file("${project.projectDir}/src/main/java/module-info.java")
    File source = file("${project.projectDir}/src/main/module-info.java")

    target.delete()
    source.renameTo(target)
}