/*
 * PICKSHADOW SERVER KIT SOURCE FILE
 * Copyright (c) 2024 The PickShadow Server Kit authors
 * Licensed under the GNU Affero General Public License v3
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

// Plugins
plugins {
    id("java")
    id("application")
    id("io.freefair.lombok") version("${pluginLombok}")
    id("io.github.goooler.shadow") version("${pluginShadow}")
}

// Dependencies
dependencies {
    // Lombok
    compileOnly("org.projectlombok:lombok:${dependencyLombok}")
    annotationProcessor("org.projectlombok:lombok:${dependencyLombok}")

    // JetBrains Annotations
    compileOnly("org.jetbrains:annotations:${dependencyJetbrainsAnnotations}")

    // Libraries
    implementation("de.staropensource.engine:base:${dependencyStarOpenSourceEngine}")
    runtimeOnly("de.staropensource.engine:ansi:${dependencyStarOpenSourceEngine}")
    implementation("com.google.code.gson:gson:${dependencyGson}")

    // Project
    implementation(project(":common"))
}

// Set Java version
java {
    toolchain.languageVersion.set(JavaLanguageVersion.of("${javaTarget}"))
}

// Fix delombok task
delombok.doFirst {
    File target = file("${project.projectDir}/src/main/module-info.java")
    File source = file("${project.projectDir}/src/main/java/module-info.java")

    target.delete()
    source.renameTo(target)
}
delombok.doLast {
    File target = file("${project.projectDir}/src/main/java/module-info.java")
    File source = file("${project.projectDir}/src/main/module-info.java")

    target.delete()
    source.renameTo(target)
}

// Configure output jar
jar {
    manifest {
        attributes(
                "Main-Class": "de.jeremystartm.pickshadow.servermanager.Main"
        )
    }
}

// Configure application run task
application {
    mainClass.set("de.jeremystartm.pickshadow.servermanager.Main")
    applicationDefaultJvmArgs = [
            // Display GC log
            "-Xlog:gc",

            // Set log level to DIAGNOSTIC
            "-Dsosengine.base.loggerLevel=diagnostic",

            // Force writing to standard output
            "-Dsosengine.base.loggerForceStandardOutput=true",

            // Pass classes which should be included if
            // reflective sclasspath scanning is disabled.
            "-Dsosengine.base.initialIncludeSubsystemClasses=de.staropensource.engine.ansi.AnsiSubsystem",

            // Force Jansi to write escape sequences
            "-Djansi.mode=force",
    ]
}