Engine/slf4j-compat/build.gradle

/*
 * STAROPENSOURCE ENGINE SOURCE FILE
 * Copyright (c) 2024 The StarOpenSource Engine Contributors
 * Licensed under the GNU Affero General Public License v3
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

plugins {
    id 'java'
    id 'io.freefair.lombok' version "${pluginLombok}"
    id 'maven-publish'
}

dependencies {
    // -> Runtime <-
    // Lombok
    compileOnly 'org.projectlombok:lombok:' + project.dependencyLombok
    annotationProcessor 'org.projectlombok:lombok:' + project.dependencyLombok

    // JetBrains Annotations
    compileOnly 'org.jetbrains:annotations:' + project.dependencyJetbrainsAnnotations
    
    // SLF4J
    implementation 'org.slf4j:slf4j-api:' + project.dependencySlf4j

    // -> Project <-
    implementation project(":base")
    implementation 'org.fusesource.jansi:jansi:' + project.dependencyJansi  // for some reason required or the build fails don't ask me why
}

javadoc.options {
    setMemberLevel(JavadocMemberLevel.PUBLIC)
    setOverview("src/main/javadoc/overview.html")
    setLocale("en_US")
    setJFlags([
            // Force Javadoc to use English translations
            "-Duser.language=en_US"
    ])
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}

publishing {
    repositories {
        maven {
            name = "staropensource"
            url = "https://mvn.staropensource.de/sosengine"
            credentials(org.gradle.api.credentials.PasswordCredentials)
            authentication {
                //noinspection GroovyAssignabilityCheck
                basic (BasicAuthentication)
            }
        }
    }
    publications {
        //noinspection GroovyAssignabilityCheck
        maven (MavenPublication) {
            groupId = group
            artifactId = "slf4j-compat"
            version = version
            //noinspection GroovyAssignabilityCheck
            from components.java
        }
    }
}