Engine/build.gradle

/*
 * STAROPENSOURCE ENGINE SOURCE FILE
 * Copyright (c) 2024 The StarOpenSource Engine Contributors
 * Licensed under the GNU Affero General Public License v3
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as
 * published by the Free Software Foundation, either version 3 of the
 * License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

// Plugins
plugins {
    id("java")
    id("io.freefair.lombok") version("${pluginLombok}")
    id("maven-publish")
}

// Register task for Javadoc generation for all subsystems
tasks.register("javadocAll", Javadoc) {
    // Task metadata
    setDescription("Generates Javadoc API documentation for all subprojects.")
    setGroup("documentation")
    dependsOn(delombok)  // Make sure the source is delomboked first

    def subprojects= [
            ":base",
            ":graphics",
            ":graphics:opengl",
            ":graphics:vulkan",
            ":slf4j-compat",
    ]

    setSource(subprojects.collect({ project(it).sourceSets.main.allJava }))
    setClasspath(files(subprojects.collect({ project(it).sourceSets.main.compileClasspath })))
    setDestinationDir(file("build/docs/javadoc"))

    options {
        if (new File(projectDir, "src/main/javadoc/theme.css").exists())
            stylesheetFile = new File(projectDir, "src/main/javadoc/theme.css")  // Theming is cool :3
        setMemberLevel(JavadocMemberLevel.PUBLIC)  // Only display public stuff
        setOverview("src/main/javadoc/overview.html")  // We want a custom overview page to greet the visitor
        setLocale("en_US")  // 你好

        setJFlags([
                "-Duser.language=en_US"  // See above
        ])
    }
}

// Set group, version and repositories for all projects
allprojects {
    group = project.group
    version = project.versioningVersion + "-" + project.versioningType + project.versioningTyperelease + project.versioningFork

    repositories {
        mavenCentral()
    }
}