Engine/build.gradle

plugins {
    id 'java'
    id "io.freefair.lombok" version "${pluginLombok}"
}

dependencies {
    // Lombok
    compileOnly 'org.projectlombok:lombok:' + project.dependencyLombok
    annotationProcessor 'org.projectlombok:lombok:' + project.dependencyLombok
}

tasks.register('javadocAll', Javadoc) {
    setDescription("Generates Javadoc API documentation for all subprojects.")
    setGroup("documentation")

    def subprojects= [
            ':base',
            ':testapp',
    ]

    setSource(subprojects.collect { project(it).sourceSets.main.allJava })
    setClasspath(files(subprojects.collect { project(it).sourceSets.main.compileClasspath }))
    setDestinationDir(file("build/docs/javadoc"))

    options {
        setMemberLevel(JavadocMemberLevel.PUBLIC)
        setOverview("src/main/javadoc/overview.html")
        setLocale("en_US")
        setJFlags([
                // Force Javadoc to use English translations
                "-Duser.language=en_US"
        ])
    }

    dependsOn delombok
}

allprojects {
    group = project.group
    version = project.versioningVersion + "-" + project.versioningType + project.versioningTyperelease + project.versioningFork

    repositories {
        mavenCentral()
    }
}